開発​/テスター​/DT132A​/スペック

-
|
|
|
|
|
|
|
!
 
 
-
|
|
|
|
-
|
|
!
|
|
|
|
|
!
 
 
 
-
-
|
|
|
|
|
|
|
-
-
-
|
-
|
!
|
|
!
|
|
|
-
|
!
|
|
!
|
!
 
-
-
-
!
|
|
|
|
|
|
-
|
-
|
!
|
!
 
-
-
|
|
|
|
|
!
 
-
-
|
|
|
!
 
-
-
|
-
!
|
|
-
!
|
|
-
!
|
|
!
 
-
-
|
-
!
|
|
-
!
|
|
-
!
|
|
!
 
-
-
|
-
!
|
|
-
!
|
|
-
!
|
|
!
 
-
-
|
-
!
|
|
-
!
|
|
-
!
|
|
!
 
-
-
|
-
!
|
!
 
-
-
|
-
!
|
!

// AstroAI DT132A EEPROM dump
// by Yuji Ueno
// Arduino      2C02A
//     SDA  --  24C02A 5pin 
//     SCL  --  24C02A 6pin
//              24C02A 7pin -- GND
//              24C02A 1,2,3pin -- GND
//     GND  --  24C02A 4pin GND
#include <Wire.h>
const int I2CADDR = 0x50;
 
void setup() {
    Serial.begin(9600);
    Wire.begin();
    
    dumpEEPROM();                                           // EEPROMをdumpする
    //set4000Count();                                         // 4000カウントに設定
    //set6000Count();                                         // 6000カウントに設定
    //set8000Count();                                         // 8000カウントに設定
    set9999Count();                                         // 9999カウントに設定
    setBacklight();                                         // バックライトを120sに設定
    setMiliACV();                                           // ACｍVを使えるようにする
    enableUART();                                           // UARTを使えるようにする
    
    dumpEEPROM();                                           // 再度EEPROMをdumpする
}
 
void loop() {}
 
// EEPROMから256byte読んで出力する
void dumpEEPROM() {
    unsigned int addrPointer = 0;
    unsigned int romLength = 0xff;                          // EEPROM 24C02A - 256 x 8bits
    byte data;
    
    delay(500);
    Serial.println("\nDT132A EEROM dump...");
    Serial.println("-- : 00 01 02 03 04 05 06 07 08 09 0A 0B 0C 0D 0E 0F");     // output header
    while (addrPointer <= romLength) {
        // output line header
        if (!(addrPointer % 16)) {
            Serial.print("\n");
            if (addrPointer < 16) {
                Serial.print("0");
            }
            Serial.print(addrPointer, HEX);
            Serial.print(" : ");
        }
        
        data = readByte(I2CADDR, addrPointer);              // Read 1byte
        addrPointer++;                                      // address pointer++
        if (data < 0x10) {
            Serial.print("0");
        }
        Serial.print(data, HEX);                            // 出力
        Serial.print(" ");
    }
    Serial.println(" ");
}
 
// EEPROMから読み込む
byte readByte(int i2cAddr, unsigned int addr) {
    //delay(100);
    byte data = 0x00;
    Wire.beginTransmission(i2cAddr);
    Wire.write(addr);
    Wire.endTransmission();
    Wire.requestFrom(i2cAddr, 1);
    while (!Wire.available()) ;
    
    if (Wire.available()){
        data = Wire.read();
    } else {
        data = 0xff;
    }
    return data;
}
 
// EEPROMに書き込む
void writeByte(int i2cAddr, unsigned int addr, byte data) {
    delay(100);
    Wire.beginTransmission(i2cAddr);
    Wire.write(addr);
    Wire.write(data);
    Wire.endTransmission();
}
 
// UART通信を出来るように設定
void enableUART() {
    Serial.println("Enabling UART...");
    writeByte(I2CADDR, 0xFA, (byte) 0xFE);
    Serial.println("Done");
}
 
// 4000カウントに設定する
void set4000Count() {
    Serial.println("Set 4000Count...");
    // カウント数の変更（0x10,0x11: 0x0FA0）
    writeByte(I2CADDR, 0x10, (byte) 0xA0);                  // set 0x0FA0 - 4000
    writeByte(I2CADDR, 0x11, (byte) 0x0F);                  // 
    
    // レンジ変更上限の変更（0x12,0x13: 0x1068）
    writeByte(I2CADDR, 0x12, (byte) 0x68);                  // set 0x1068 - 4200
    writeByte(I2CADDR, 0x13, (byte) 0x10);                  //
    
    // レンジ変更加減の変更（0x12,0x13: 0x017C)
    writeByte(I2CADDR, 0x14, (byte) 0x7C);                  // set 0x017C - 380
    writeByte(I2CADDR, 0x15, (byte) 0x01);                  //
    Serial.println("Done");
}
 
// 6000カウントに設定する
void set6000Count() {
    Serial.println("Set 6000Count...");
    // カウント数の変更（0x10,0x11: 0x1770）
    writeByte(I2CADDR, 0x10, (byte) 0x70);                  // set 0x1770 - 6000
    writeByte(I2CADDR, 0x11, (byte) 0x17);                  // 
    
    // レンジ変更上限の変更（0x12,0x13: 0x1771）
    writeByte(I2CADDR, 0x12, (byte) 0x38);                  // set 0x1771 - 6200
    writeByte(I2CADDR, 0x13, (byte) 0x18);                  //
    
    // レンジ変更加減の変更（0x12,0x13: 0x0244）
    writeByte(I2CADDR, 0x14, (byte) 0x44);                  // set 0x0244 - 580
    writeByte(I2CADDR, 0x15, (byte) 0x02);                  //
    Serial.println("Done");
}
 
// 8000カウントに設定する
void set8000Count() {
    Serial.println("Set 8000Count...");
    // カウント数の変更（0x10,0x11: 0x1F40）
    writeByte(I2CADDR, 0x10, (byte) 0x40);                  // set 0x1F40 - 8000
    writeByte(I2CADDR, 0x11, (byte) 0x1F);                  // 
    
    // レンジ変更上限の変更（0x12,0x13: 0x2008）
    writeByte(I2CADDR, 0x12, (byte) 0x08);                  // set 0x2008 - 8200
    writeByte(I2CADDR, 0x13, (byte) 0x20);                  // 
    
    // レンジ変更加減の変更（0x12,0x13: 0x02EE）
    writeByte(I2CADDR, 0x14, (byte) 0xEE);                  // set 0x02EE - 750
    writeByte(I2CADDR, 0x15, (byte) 0x02);                  // 
    Serial.println("Done");
}
 
// 9999カウントに設定する
void set9999Count() {
    Serial.println("Set 9999Count...");
    // カウント数の変更（0x10,0x11: 0x270F）
    writeByte(I2CADDR, 0x10, (byte) 0x0F);                  // set 0x270F - 9999
    writeByte(I2CADDR, 0x11, (byte) 0x27);                  // 
    
    // レンジ変更上限の変更（0x12,0x13: 0x270F）
    writeByte(I2CADDR, 0x12, (byte) 0x0F);                  // set 0x270F - 9999
    writeByte(I2CADDR, 0x13, (byte) 0x27);                  // 
    
    // レンジ変更加減の変更（0x12,0x13: 0x03D4）
    writeByte(I2CADDR, 0x14, (byte) 0xD4);                  // set 0x03D4 - 980
    writeByte(I2CADDR, 0x15, (byte) 0x03);                  // 
    Serial.println("Done");
}
 
// バックライト持続時間の設定
void setBacklight() {
    Serial.println("set Backlight Time...");
    // バックライト持続時間の変更（0xFC： 0x0F -> 0x78）
    writeByte(I2CADDR, 0xFC, (byte) 0x78);                  // set 0x78 - 120s
    Serial.println("Done");
}
 
// mVACを使えるようにする設定
void setMiliACV() {
    Serial.println("set mVAC...");
    // ACVにmVから測定出来るようにする（0x8E: 0x04 -> 0x06）
    writeByte(I2CADDR, 0x8E, (byte) 0x06);                  // set 0x06 - mVACV
    Serial.println("Done");
}