PC​/IRリモコン

-
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
!
 
 
 
 
 
-
!
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
-
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
!
 
-
-
|
|
|
|
|
|
|
|
-
|
|
|
|
|
|
|
|
|
|
-
-
|
|
!
!
|
!
-
|
|
|
-
|
|
|
|
|
|
|
|
|
|
|
|
|
|
!
!
|
!
 
-
-
|
|
|
|
|
|
|
|
|
|
|
|
|
|
|
!

// rcvsend
// by Yuji Ueno
// AVRIRでのIRリモコンの受信・送信のテストプログラム
// ・待機中にリモコン信号を受信するとデータをEEPROMに保存する（学習）
// ・MOSI(MISO)端子をLowにすると保存したデータを送信する（1s毎に再送信）
// ・シリアルコンソールに情報を表示する
// ・IRRemoteライブラリを使用
// 
// ハードウェア
// 
// IR受信センサー            ATMEL AVR Board
// HX1838                    ATmega168p
// +---------+               +----------(
// |   OUT 1 |---------------|PD2 受信   )
// |   GND 2 |---------------|GND         
// |   VCC 3 |---------------|+5V         
// +---------+               |            
//          +------ R -------|PD3 送信    
//          |A    82ohm      |            
//        IR LED             |            
//          |K               |            
//          +----------------|GND         
//                           |         (  
//                           +----------) 
//
#define MARK_EXCESS_MICROS 20
#define RAW_BUFFER_LENGTH 200
 
#include <IRremote.hpp>
#include <avr/eeprom.h>
 
//#define SW MISO                                                   // 送信SW PB4 MISO
#define SW MOSI                                                 // 送信SW PB4 MOSI(piramp)
#define LED LED_BUILTIN                                         // onボード LED
#define PUSH 1000                                               // 送信SW確認用
 
#define EEPROM_V1 0x0000                                        // dataを保存するEEPROMのアドレス
#define EEPROM_V2 0x0004                                        // bitsを保存するEEPROMのアドレス
#define EEPROM_V3 0x0005                                        // bitsを保存するEEPROMのアドレス
 
int IR_RECEIVE_PIN = 2;                                         // IRセンサーを接続するポートPD2
int IR_SEND_PIN = 3;                                            // IR LEDを接続するポートPD3
 
long recdata;                                                   // data temp.
byte recbits;                                                   // bits temp.
byte rectype;                                                   // protocol temp.
byte recflags;                                                  // flags temp.
uint16_t recaddr,reccom,recextra;                               // address, command, extra temp.
 
int swcount;                                                    // 送信SW counter
 
void setup() {
    digitalWrite(LED, LOW);                                     // LED off
    Serial.begin(9600);                                         // init comポート(9600)
    pinMode(SW, INPUT_PULLUP);                                  // SWポートをプルアップ
    pinMode(LED, OUTPUT);                                       // LEDポートを出力モードに設定
    IrReceiver.begin(IR_RECEIVE_PIN, DISABLE_LED_FEEDBACK);     // IR受信を開始
    IrSender.begin(IR_SEND_PIN, DISABLE_LED_FEEDBACK, LED);     // IR送信を開始
 
    swcount = 0;                                                // init SW counter
    
    eeprom_busy_wait();
    recdata = eeprom_read_dword((uint32_t *)EEPROM_V1);         // EEPROMからdataを読み出す
    eeprom_busy_wait();
    recbits = eeprom_read_byte((uint8_t *)EEPROM_V2);           // EEPROMからbitsを読み出す
    eeprom_busy_wait();
    rectype = eeprom_read_byte((uint8_t *)EEPROM_V3);           // EEPROMからtypeを読み出す
    
    Serial.print("rcv and send IR remokon signal.\n");          // startup表示
    SPRI();                                                     // データ表示
}
 
void loop() {
    if (IrReceiver.decode()) {                                  // IRリモコン受信?
        recbits = IrReceiver.decodedIRData.numberOfBits;        // IRビット長をRAMに保存
        recflags = IrReceiver.decodedIRData.flags;              // IRビット長をRAMに保存
        recdata = IrReceiver.decodedIRData.decodedRawData;      // IRデータをRAMに保存
        rectype = IrReceiver.decodedIRData.protocol;            // IR受信プロトコルをRAMに保存
        recaddr = IrReceiver.decodedIRData.address;             // IR受信アドレスを保存
        reccom = IrReceiver.decodedIRData.command;              // IR受信コマンドを保存
        recextra = IrReceiver.decodedIRData.extra;              // IR受信extraデータを保存
                
        if (rectype != 0){
            eeprom_busy_wait();
            eeprom_update_dword((uint32_t *)EEPROM_V1, recdata);// EEPROMにdataを保存
            eeprom_busy_wait();
            eeprom_update_byte((uint8_t *)EEPROM_V2, recbits);  // EEPROMにbitsを保存
            eeprom_busy_wait();
            eeprom_update_byte((uint8_t *)EEPROM_V3, rectype);  // EEPROMにtypeを保存
            
            Serial.print("Memorized! ");                        // メモリー表示
            SPRI();                                             // データ表示
            
            // リモコンを学習したらLEDを点滅
            for (byte i = 0 ; i < 5 ; i++) {
                digitalWrite(LED, i % 2);
                delay(100);
            }
        }
        IrReceiver.resume();                                    // 次の受信の準備       
    }
    while (digitalRead(SW) == 0) {                              // sw on?
        digitalWrite(LED, HIGH);                                // LED on
        swcount++;                                              // sw onされている場合Counter +1する
        
        if (swcount > PUSH) {                                   // counterがPUSH以上だったら?
            eeprom_busy_wait();
            recdata = eeprom_read_dword((uint32_t *)EEPROM_V1); // EEPROMからdataを読み出す
            eeprom_busy_wait();
            recbits = eeprom_read_byte((uint8_t *)EEPROM_V2);   // EEPROMからbitsを読み出す
            eeprom_busy_wait();
            rectype = eeprom_read_byte((uint8_t *)EEPROM_V3);   // EEPROMからtypeを読み出す
                        
            IrSender.sendNECRaw(recdata, 3);                    // 送信する
            Serial.print("SEND! ");                             // 送信表示
            SPRI();                                             // データ表示
            digitalWrite(LED, LOW);                             // LEDをオフ
            delay(1000);                                        // wait 1s
            IrReceiver.resume();                                // 次の受信の準備（irsendすると受信が停止するため）
            swcount = 0;                                        // counterをクリヤー
        }
    }
    swcount = 0;                                                // counterをクリヤー
}
 
// 情報の表示
void SPRI() {
    Serial.print("> Protocol:");
    Serial.print(getProtocolString(rectype));                   // protocol表示
    Serial.print(" BITS:");
    Serial.print(recbits);                                      // bit表示
    Serial.print(" FLAG:");
    Serial.print(recflags);                                     // flags表示
    Serial.print(" ADDR:0x");
    Serial.print(recaddr, HEX);                                 // address表示
    Serial.print(" CMD:0x");
    Serial.print(reccom, HEX);                                  // command表示
    Serial.print(" EXTD:0x");
    Serial.print(recextra, HEX);                                // extra data表示   
    Serial.print(" DATA:0x");
    Serial.print(recdata, HEX);                                 // data表示
    Serial.println();
}